home *** CD-ROM | disk | FTP | other *** search
/ The Arsenal Files 8 / The Arsenal Files Collection #8 (Arsenal Computer) (1996).ISO / g_quake / ffield.zip / CLIENT.QC < prev    next >
Text File  |  1996-10-13  |  34KB  |  1,442 lines
  1.  
  2. // prototypes
  3. void () W_WeaponFrame;
  4. void() W_SetCurrentAmmo;
  5. void() player_pain;
  6. void() player_stand1;
  7. void (vector org) spawn_tfog;
  8. void (vector org, entity death_owner) spawn_tdeath;
  9.  
  10. float    modelindex_eyes, modelindex_player;
  11.  
  12. /*
  13. =============================================================================
  14.  
  15.                 LEVEL CHANGING / INTERMISSION
  16.  
  17. =============================================================================
  18. */
  19.  
  20. float    intermission_running;
  21. float    intermission_exittime;
  22.  
  23. /*QUAKED info_intermission (1 0.5 0.5) (-16 -16 -16) (16 16 16)
  24. This is the camera point for the intermission.
  25. Use mangle instead of angle, so you can set pitch or roll as well as yaw.  'pitch roll yaw'
  26. */
  27. void() info_intermission =
  28. {
  29. };
  30.  
  31.  
  32.  
  33. void() SetChangeParms =
  34. {
  35. // remove items
  36.     self.items = self.items - (self.items & 
  37.     (IT_KEY1 | IT_KEY2 | IT_INVISIBILITY | IT_INVULNERABILITY | IT_SUIT | IT_QUAD) );
  38.     
  39. // cap super health
  40.     if (self.health > 100)
  41.         self.health = 100;
  42.     if (self.health < 50)
  43.         self.health = 50;
  44.     parm1 = self.items;
  45.     parm2 = self.health;
  46.     parm3 = self.armorvalue;
  47.     if (self.ammo_shells < 25)
  48.         parm4 = 25;
  49.     else
  50.         parm4 = self.ammo_shells;
  51.     parm5 = self.ammo_nails;
  52.     parm6 = self.ammo_rockets;
  53.     parm7 = self.ammo_cells;
  54.     parm8 = self.weapon;
  55.     parm9 = self.armortype * 100;
  56. };
  57.  
  58. void() SetNewParms =
  59. {
  60.     parm1 = IT_SHOTGUN | IT_AXE;
  61.     parm2 = 100;
  62.     parm3 = 0;
  63.     parm4 = 25;
  64.     parm5 = 0;
  65.     parm6 = 0;
  66.     parm6 = 0;
  67.     parm8 = 1;
  68.     parm9 = 0;
  69. };
  70.  
  71. void() DecodeLevelParms =
  72. {
  73.     if (serverflags)
  74.     {
  75.         if (world.model == "maps/start.bsp")
  76.             SetNewParms ();        // take away all stuff on starting new episode
  77.     }
  78.     
  79.     self.items = parm1;
  80.     self.health = parm2;
  81.     self.armorvalue = parm3;
  82.     self.ammo_shells = parm4;
  83.     self.ammo_nails = parm5;
  84.     self.ammo_rockets = parm6;
  85.     self.ammo_cells = parm7;
  86.     self.weapon = parm8;
  87.     self.armortype = parm9 * 0.01;
  88. };
  89.  
  90. /*
  91. ============
  92. FindIntermission
  93.  
  94. Returns the entity to view from
  95. ============
  96. */
  97. entity() FindIntermission =
  98. {
  99.     local    entity spot;
  100.     local    float cyc;
  101.  
  102. // look for info_intermission first
  103.     spot = find (world, classname, "info_intermission");
  104.     if (spot)
  105.     {    // pick a random one
  106.         cyc = random() * 4;
  107.         while (cyc > 1)
  108.         {
  109.             spot = find (spot, classname, "info_intermission");
  110.             if (!spot)
  111.                 spot = find (spot, classname, "info_intermission");
  112.             cyc = cyc - 1;
  113.         }
  114.         return spot;
  115.     }
  116.  
  117. // then look for the start position
  118.     spot = find (world, classname, "info_player_start");
  119.     if (spot)
  120.         return spot;
  121.     
  122. // testinfo_player_start is only found in regioned levels
  123.     spot = find (world, classname, "testplayerstart");
  124.     if (spot)
  125.         return spot;
  126.     
  127.     objerror ("FindIntermission: no spot");
  128. };
  129.  
  130.  
  131. string nextmap;
  132. void() GotoNextMap =
  133. {
  134.     if (cvar("samelevel"))    // if samelevel is set, stay on same level
  135.         changelevel (mapname);
  136.     else
  137.         changelevel (nextmap);
  138. };
  139.  
  140.  
  141. void() ExitIntermission =
  142. {
  143. // skip any text in deathmatch
  144.     if (deathmatch)
  145.     {
  146.         GotoNextMap ();
  147.         return;
  148.     }
  149.     
  150.     intermission_exittime = time + 1;
  151.     intermission_running = intermission_running + 1;
  152.  
  153. //
  154. // run some text if at the end of an episode
  155. //
  156.     if (intermission_running == 2)
  157.     {
  158.         if (world.model == "maps/e1m7.bsp")
  159.         {
  160.             WriteByte (MSG_ALL, SVC_CDTRACK);
  161.             WriteByte (MSG_ALL, 2);
  162.             WriteByte (MSG_ALL, 3);
  163.             if (!cvar("registered"))
  164.             {
  165.                 WriteByte (MSG_ALL, SVC_FINALE);
  166.                 WriteString (MSG_ALL, "As the corpse of the monstrous entity\nChthon sinks back into the lava whence\nit rose, you grip the Rune of Earth\nMagic tightly. Now that you have\nconquered the Dimension of the Doomed,\nrealm of Earth Magic, you are ready to\ncomplete your task in the other three\nhaunted lands of Quake. Or are you? If\nyou don't register Quake, you'll never\nknow what awaits you in the Realm of\nBlack Magic, the Netherworld, and the\nElder World!");
  167.             }
  168.             else
  169.             {
  170.                 WriteByte (MSG_ALL, SVC_FINALE);
  171.                 WriteString (MSG_ALL, "As the corpse of the monstrous entity\nChthon sinks back into the lava whence\nit rose, you grip the Rune of Earth\nMagic tightly. Now that you have\nconquered the Dimension of the Doomed,\nrealm of Earth Magic, you are ready to\ncomplete your task. A Rune of magic\npower lies at the end of each haunted\nland of Quake. Go forth, seek the\ntotality of the four Runes!");
  172.             }
  173.             return;
  174.         }
  175.         else if (world.model == "maps/e2m6.bsp")
  176.         {
  177.             WriteByte (MSG_ALL, SVC_CDTRACK);
  178.             WriteByte (MSG_ALL, 2);
  179.             WriteByte (MSG_ALL, 3);
  180.  
  181.             WriteByte (MSG_ALL, SVC_FINALE);
  182.             WriteString (MSG_ALL, "The Rune of Black Magic throbs evilly in\nyour hand and whispers dark thoughts\ninto your brain. You learn the inmost\nlore of the Hell-Mother; Shub-Niggurath!\nYou now know that she is behind all the\nterrible plotting which has led to so\nmuch death and horror. But she is not\ninviolate! Armed with this Rune, you\nrealize that once all four Runes are\ncombined, the gate to Shub-Niggurath's\nPit will open, and you can face the\nWitch-Goddess herself in her frightful\notherworld cathedral.");
  183.             return;
  184.         }
  185.         else if (world.model == "maps/e3m6.bsp")
  186.         {
  187.             WriteByte (MSG_ALL, SVC_CDTRACK);
  188.             WriteByte (MSG_ALL, 2);
  189.             WriteByte (MSG_ALL, 3);
  190.  
  191.             WriteByte (MSG_ALL, SVC_FINALE);
  192.             WriteString (MSG_ALL, "The charred viscera of diabolic horrors\nbubble viscously as you seize the Rune\nof Hell Magic. Its heat scorches your\nhand, and its terrible secrets blight\nyour mind. Gathering the shreds of your\ncourage, you shake the devil's shackles\nfrom your soul, and become ever more\nhard and determined to destroy the\nhideous creatures whose mere existence\nthreatens the souls and psyches of all\nthe population of Earth.");
  193.             return;
  194.         }
  195.         else if (world.model == "maps/e4m7.bsp")
  196.         {
  197.             WriteByte (MSG_ALL, SVC_CDTRACK);
  198.             WriteByte (MSG_ALL, 2);
  199.             WriteByte (MSG_ALL, 3);
  200.  
  201.             WriteByte (MSG_ALL, SVC_FINALE);
  202.             WriteString (MSG_ALL, "Despite the awful might of the Elder\nWorld, you have achieved the Rune of\nElder Magic, capstone of all types of\narcane wisdom. Beyond good and evil,\nbeyond life and death, the Rune\npulsates, heavy with import. Patient and\npotent, the Elder Being Shub-Niggurath\nweaves her dire plans to clear off all\nlife from the Earth, and bring her own\nfoul offspring to our world! For all the\ndwellers in these nightmare dimensions\nare her descendants! Once all Runes of\nmagic power are united, the energy\nbehind them will blast open the Gateway\nto Shub-Niggurath, and you can travel\nthere to foil the Hell-Mother's plots\nin person.");
  203.             return;
  204.         }
  205.  
  206.         GotoNextMap();
  207.     }
  208.     
  209.     if (intermission_running == 3)
  210.     {
  211.         if (!cvar("registered"))
  212.         {    // shareware episode has been completed, go to sell screen
  213.             WriteByte (MSG_ALL, SVC_SELLSCREEN);
  214.             return;
  215.         }
  216.         
  217.         if ( (serverflags&15) == 15)
  218.         {
  219.             WriteByte (MSG_ALL, SVC_FINALE);
  220.             WriteString (MSG_ALL, "Now, you have all four Runes. You sense\ntremendous invisible forces moving to\nunseal ancient barriers. Shub-Niggurath\nhad hoped to use the Runes Herself to\nclear off the Earth, but now instead,\nyou will use them to enter her home and\nconfront her as an avatar of avenging\nEarth-life. If you defeat her, you will\nbe remembered forever as the savior of\nthe planet. If she conquers, it will be\nas if you had never been born.");
  221.             return;
  222.         }
  223.         
  224.     }
  225.  
  226.     GotoNextMap();
  227. };
  228.  
  229. /*
  230. ============
  231. IntermissionThink
  232.  
  233. When the player presses attack or jump, change to the next level
  234. ============
  235. */
  236. void() IntermissionThink =
  237. {
  238.     if (time < intermission_exittime)
  239.         return;
  240.  
  241.     if (!self.button0 && !self.button1 && !self.button2)
  242.         return;
  243.     
  244.     ExitIntermission ();
  245. };
  246.  
  247. void() execute_changelevel =
  248. {
  249.     local entity    pos;
  250.  
  251.     intermission_running = 1;
  252.     
  253. // enforce a wait time before allowing changelevel
  254.     if (deathmatch)
  255.         intermission_exittime = time + 5;
  256.     else
  257.         intermission_exittime = time + 2;
  258.  
  259.     WriteByte (MSG_ALL, SVC_CDTRACK);
  260.     WriteByte (MSG_ALL, 3);
  261.     WriteByte (MSG_ALL, 3);
  262.     
  263.     pos = FindIntermission ();
  264.  
  265.     other = find (world, classname, "player");
  266.     while (other != world)
  267.     {
  268.         other.view_ofs = '0 0 0';
  269.         other.angles = other.v_angle = pos.mangle;
  270.         other.fixangle = TRUE;        // turn this way immediately
  271.         other.nextthink = time + 0.5;
  272.         other.takedamage = DAMAGE_NO;
  273.         other.solid = SOLID_NOT;
  274.         other.movetype = MOVETYPE_NONE;
  275.         other.modelindex = 0;
  276.         setorigin (other, pos.origin);
  277.         other = find (other, classname, "player");
  278.     }    
  279.  
  280.     WriteByte (MSG_ALL, SVC_INTERMISSION);
  281. };
  282.  
  283.  
  284. void() changelevel_touch =
  285. {
  286.     local entity    pos;
  287.  
  288.     if (other.classname != "player")
  289.         return;
  290.  
  291.     if (cvar("noexit"))
  292.     {
  293.         T_Damage (other, self, self, 50000);
  294.         return;
  295.     }
  296.     bprint (other.netname);
  297.     bprint (" exited the level\n");
  298.     
  299.     nextmap = self.map;
  300.  
  301.     SUB_UseTargets ();
  302.  
  303.     if ( (self.spawnflags & 1) && (deathmatch == 0) )
  304.     {    // NO_INTERMISSION
  305.         GotoNextMap();
  306.         return;
  307.     }
  308.     
  309.     self.touch = SUB_Null;
  310.  
  311. // we can't move people right now, because touch functions are called
  312. // in the middle of C movement code, so set a think time to do it
  313.     self.think = execute_changelevel;
  314.     self.nextthink = time + 0.1;
  315. };
  316.  
  317. /*QUAKED trigger_changelevel (0.5 0.5 0.5) ? NO_INTERMISSION
  318. When the player touches this, he gets sent to the map listed in the "map" variable.  Unless the NO_INTERMISSION flag is set, the view will go to the info_intermission spot and display stats.
  319. */
  320. void() trigger_changelevel =
  321. {
  322.     if (!self.map)
  323.         objerror ("chagnelevel trigger doesn't have map");
  324.     
  325.     InitTrigger ();
  326.     self.touch = changelevel_touch;
  327. };
  328.  
  329.  
  330. /*
  331. =============================================================================
  332.  
  333.                 PLAYER GAME EDGE FUNCTIONS
  334.  
  335. =============================================================================
  336. */
  337.  
  338. void() set_suicide_frame;
  339.  
  340. // called by ClientKill and DeadThink
  341. void() respawn =
  342. {
  343.     if (coop)
  344.     {
  345.         // make a copy of the dead body for appearances sake
  346.         CopyToBodyQue (self);
  347.         // get the spawn parms as they were at level start
  348.         setspawnparms (self);
  349.         // respawn        
  350.         PutClientInServer ();
  351.     }
  352.     else if (deathmatch)
  353.     {
  354.         // make a copy of the dead body for appearances sake
  355.         CopyToBodyQue (self);
  356.         // set default spawn parms
  357.         SetNewParms ();
  358.         // respawn        
  359.         PutClientInServer ();
  360.     }
  361.     else
  362.     {    // restart the entire server
  363.         localcmd ("restart\n");
  364.     }
  365. };
  366.  
  367.  
  368. /*
  369. ============
  370. ClientKill
  371.  
  372. Player entered the suicide command
  373. ============
  374. */
  375. void() ClientKill =
  376. {
  377.     bprint (self.netname);
  378.     bprint (" suicides\n");
  379.     set_suicide_frame ();
  380.     self.modelindex = modelindex_player;
  381.     self.frags = self.frags - 2;    // extra penalty
  382.     respawn ();
  383. };
  384.  
  385. float(vector v) CheckSpawnPoint =
  386. {
  387.     return FALSE;
  388. };
  389.  
  390. /*
  391. ============
  392. SelectSpawnPoint
  393.  
  394. Returns the entity to spawn at
  395. ============
  396. */
  397. entity() SelectSpawnPoint =
  398. {
  399.     local    entity spot;
  400.     
  401. // testinfo_player_start is only found in regioned levels
  402.     spot = find (world, classname, "testplayerstart");
  403.     if (spot)
  404.         return spot;
  405.         
  406. // choose a info_player_deathmatch point
  407.     if (coop)
  408.     {
  409.         lastspawn = find(lastspawn, classname, "info_player_coop");
  410.         if (lastspawn == world)
  411.             lastspawn = find (lastspawn, classname, "info_player_start");
  412.         if (lastspawn != world)
  413.             return lastspawn;
  414.     }
  415.     else if (deathmatch)
  416.     {
  417.         lastspawn = find(lastspawn, classname, "info_player_deathmatch");
  418.         if (lastspawn == world)
  419.             lastspawn = find (lastspawn, classname, "info_player_deathmatch");
  420.         if (lastspawn != world)
  421.             return lastspawn;
  422.     }
  423.  
  424.     if (serverflags)
  425.     {    // return with a rune to start
  426.         spot = find (world, classname, "info_player_start2");
  427.         if (spot)
  428.             return spot;
  429.     }
  430.     
  431.     spot = find (world, classname, "info_player_start");
  432.     if (!spot)
  433.         error ("PutClientInServer: no info_player_start on level");
  434.     
  435.     return spot;
  436. };
  437.  
  438. /*
  439. ===========
  440. PutClientInServer
  441.  
  442. called each time a player is spawned
  443. ============
  444. */
  445. void() DecodeLevelParms;
  446. void() PlayerDie;
  447.  
  448.  
  449. void() PutClientInServer =
  450. {
  451.     local    entity spot;
  452.  
  453.     self.classname = "player";
  454.     self.health = 100;
  455.     self.takedamage = DAMAGE_AIM;
  456.     self.solid = SOLID_SLIDEBOX;
  457.     self.movetype = MOVETYPE_WALK;
  458.     self.show_hostile = 0;
  459.     self.max_health = 100;
  460.     self.flags = FL_CLIENT;
  461.     self.air_finished = time + 12;
  462.     self.dmg = 2;           // initial water damage
  463.     self.super_damage_finished = 0;
  464.     self.radsuit_finished = 0;
  465.     self.invisible_finished = 0;
  466.     self.invincible_finished = 0;
  467.     self.effects = 0;
  468.     self.invincible_time = 0;
  469. // <JRS> (Initialize Variables)
  470.     self.Union_ForceField_On = FALSE;
  471.         self.Union_FF_HasItem = FALSE;
  472. // </JRS>
  473.  
  474.     DecodeLevelParms ();
  475.     
  476.     W_SetCurrentAmmo ();
  477.  
  478.     self.attack_finished = time;
  479.     self.th_pain = player_pain;
  480.     self.th_die = PlayerDie;
  481.     
  482.     self.deadflag = DEAD_NO;
  483. // paustime is set by teleporters to keep the player from moving a while
  484.     self.pausetime = 0;
  485.     
  486.     spot = SelectSpawnPoint ();
  487.  
  488.     self.origin = spot.origin + '0 0 1';
  489.     self.angles = spot.angles;
  490.     self.fixangle = TRUE;        // turn this way immediately
  491.  
  492. // oh, this is a hack!
  493.     setmodel (self, "progs/eyes.mdl");
  494.     modelindex_eyes = self.modelindex;
  495.  
  496.     setmodel (self, "progs/player.mdl");
  497.     modelindex_player = self.modelindex;
  498.  
  499.     setsize (self, VEC_HULL_MIN, VEC_HULL_MAX);
  500.     
  501.     self.view_ofs = '0 0 22';
  502.  
  503.     player_stand1 ();
  504.     
  505.     if (deathmatch || coop)
  506.     {
  507.         makevectors(self.angles);
  508.         spawn_tfog (self.origin + v_forward*20);
  509.     }
  510.  
  511.     spawn_tdeath (self.origin, self);
  512. };
  513.  
  514.  
  515. /*
  516. =============================================================================
  517.  
  518.                 QUAKED FUNCTIONS
  519.  
  520. =============================================================================
  521. */
  522.  
  523.  
  524. /*QUAKED info_player_start (1 0 0) (-16 -16 -24) (16 16 24)
  525. The normal starting point for a level.
  526. */
  527. void() info_player_start =
  528. {
  529. };
  530.  
  531.  
  532. /*QUAKED info_player_start2 (1 0 0) (-16 -16 -24) (16 16 24)
  533. Only used on start map for the return point from an episode.
  534. */
  535. void() info_player_start2 =
  536. {
  537. };
  538.  
  539.  
  540. /*
  541. saved out by quaked in region mode
  542. */
  543. void() testplayerstart =
  544. {
  545. };
  546.  
  547. /*QUAKED info_player_deathmatch (1 0 1) (-16 -16 -24) (16 16 24)
  548. potential spawning position for deathmatch games
  549. */
  550. void() info_player_deathmatch =
  551. {
  552. };
  553.  
  554. /*QUAKED info_player_coop (1 0 1) (-16 -16 -24) (16 16 24)
  555. potential spawning position for coop games
  556. */
  557. void() info_player_coop =
  558. {
  559. };
  560.  
  561. /*
  562. ===============================================================================
  563.  
  564. RULES
  565.  
  566. ===============================================================================
  567. */
  568.  
  569. void(entity c) PrintClientScore =
  570. {
  571.     if (c.frags > -10 && c.frags < 0)
  572.         bprint (" ");
  573.     else if (c.frags >= 0)
  574.     {
  575.         if (c.frags < 100)
  576.             bprint (" ");
  577.         if (c.frags < 10)
  578.             bprint (" ");
  579.     }
  580.     bprint (ftos(c.frags));
  581.     bprint (" ");
  582.     bprint (c.netname);
  583.     bprint ("\n");
  584. };
  585.  
  586. void() DumpScore =
  587. {
  588.     local entity    e, sort, walk;
  589.  
  590.     if (world.chain)
  591.         error ("DumpScore: world.chain is set");
  592.  
  593. // build a sorted lis
  594.     e = find(world, classname, "player");
  595.     sort = world;
  596.     while (e)
  597.     {
  598.         if (!sort)
  599.         {
  600.             sort = e;
  601.             e.chain = world;
  602.         }
  603.         else
  604.         {
  605.             if (e.frags > sort.frags)
  606.             {
  607.                 e.chain = sort;
  608.                 sort = e;
  609.             }
  610.             else
  611.             {
  612.                 walk = sort;
  613.                 do
  614.                 {
  615.                     if (!walk.chain)
  616.                     {
  617.                         e.chain = world;
  618.                         walk.chain = e;
  619.                     }
  620.                     else if (walk.chain.frags < e.frags)
  621.                     {
  622.                         e.chain = walk.chain;
  623.                         walk.chain = e;
  624.                     }
  625.                     else
  626.                         walk = walk.chain;
  627.                 } while (walk.chain != e);
  628.             }
  629.         }
  630.         
  631.         e = find(e, classname, "player");
  632.     }
  633.  
  634. // print the list
  635.     
  636.     bprint ("\n");    
  637.     while (sort)
  638.     {
  639.         PrintClientScore (sort);
  640.         sort = sort.chain;
  641.     }
  642.     bprint ("\n");
  643. };
  644.  
  645. /*
  646. go to the next level for deathmatch
  647. */
  648. void() NextLevel =
  649. {
  650.     local entity o;
  651.  
  652. // find a trigger changelevel
  653.     o = find(world, classname, "trigger_changelevel");
  654.     if (!o || mapname == "start")
  655.     {    // go back to same map if no trigger_changelevel
  656.         o = spawn();
  657.         o.map = mapname;
  658.     }
  659.  
  660.     nextmap = o.map;
  661.     
  662.     if (o.nextthink < time)
  663.     {
  664.         o.think = execute_changelevel;
  665.         o.nextthink = time + 0.1;
  666.     }
  667. };
  668.  
  669. /*
  670. ============
  671. CheckRules
  672.  
  673. Exit deathmatch games upon conditions
  674. ============
  675. */
  676. void() CheckRules =
  677. {
  678.     local    float        timelimit;
  679.     local    float        fraglimit;
  680.     
  681.     if (gameover)    // someone else quit the game already
  682.         return;
  683.         
  684.     timelimit = cvar("timelimit") * 60;
  685.     fraglimit = cvar("fraglimit");
  686.     
  687.     if (timelimit && time >= timelimit)
  688.     {
  689. NextLevel ();
  690. /*
  691.         gameover = TRUE;
  692.         bprint ("\n\n\n==============================\n");
  693.         bprint ("game exited after ");
  694.         bprint (ftos(timelimit/60));
  695.         bprint (" minutes\n");
  696.         DumpScore ();
  697.         localcmd ("killserver\n");
  698. */
  699.         return;
  700.     }
  701.     
  702.     if (fraglimit && self.frags >= fraglimit)
  703.     {
  704. NextLevel ();
  705. /*
  706.         gameover = TRUE;
  707.         bprint ("\n\n\n==============================\n");
  708.         bprint ("game exited after ");
  709.         bprint (ftos(self.frags));
  710.         bprint (" frags\n");
  711.         DumpScore ();
  712.         localcmd ("killserver\n");
  713. */
  714.         return;
  715.     }    
  716. };
  717.  
  718. //============================================================================
  719.  
  720. void() PlayerDeathThink =
  721. {
  722.     local entity    old_self;
  723.     local float        forward;
  724.  
  725.     if ((self.flags & FL_ONGROUND))
  726.     {
  727.         forward = vlen (self.velocity);
  728.         forward = forward - 20;
  729.         if (forward <= 0)
  730.             self.velocity = '0 0 0';
  731.         else    
  732.             self.velocity = forward * normalize(self.velocity);
  733.     }
  734.  
  735. // wait for all buttons released
  736.     if (self.deadflag == DEAD_DEAD)
  737.     {
  738.         if (self.button2 || self.button1 || self.button0)
  739.             return;
  740.         self.deadflag = DEAD_RESPAWNABLE;
  741.         return;
  742.     }
  743.  
  744. // wait for any button down
  745.     if (!self.button2 && !self.button1 && !self.button0)
  746.         return;
  747.  
  748.     self.button0 = 0;
  749.     self.button1 = 0;
  750.     self.button2 = 0;
  751.     respawn();
  752. };
  753.  
  754.  
  755. void() PlayerJump =
  756. {
  757.     local vector start, end;
  758.     
  759.     if (self.flags & FL_WATERJUMP)
  760.         return;
  761.     
  762.     if (self.waterlevel >= 2)
  763.     {
  764.         if (self.watertype == CONTENT_WATER)
  765.             self.velocity_z = 100;
  766.         else if (self.watertype == CONTENT_SLIME)
  767.             self.velocity_z = 80;
  768.         else
  769.             self.velocity_z = 50;
  770.  
  771. // play swiming sound
  772.         if (self.swim_flag < time)
  773.         {
  774.             self.swim_flag = time + 1;
  775.             if (random() < 0.5)
  776.                 sound (self, CHAN_BODY, "misc/water1.wav", 1, ATTN_NORM);
  777.             else
  778.                 sound (self, CHAN_BODY, "misc/water2.wav", 1, ATTN_NORM);
  779.         }
  780.  
  781.         return;
  782.     }
  783.  
  784.     if (!(self.flags & FL_ONGROUND))
  785.         return;
  786.  
  787.     if ( !(self.flags & FL_JUMPRELEASED) )
  788.         return;        // don't pogo stick
  789.  
  790.     self.flags = self.flags - (self.flags & FL_JUMPRELEASED);
  791.  
  792.     self.flags = self.flags - FL_ONGROUND;    // don't stairwalk
  793.     
  794.     self.button2 = 0;
  795. // player jumping sound
  796.     sound (self, CHAN_BODY, "player/plyrjmp8.wav", 1, ATTN_NORM);
  797.     self.velocity_z = self.velocity_z + 270;
  798. };
  799.  
  800.  
  801. /*
  802. ===========
  803. WaterMove
  804.  
  805. ============
  806. */
  807. .float    dmgtime;
  808.  
  809. void() WaterMove =
  810. {
  811. //dprint (ftos(self.waterlevel));
  812.     if (self.movetype == MOVETYPE_NOCLIP)
  813.         return;
  814.     if (self.health < 0)
  815.         return;
  816.  
  817.     if (self.waterlevel != 3)
  818.     {
  819.         if (self.air_finished < time)
  820.             sound (self, CHAN_VOICE, "player/gasp2.wav", 1, ATTN_NORM);
  821.         else if (self.air_finished < time + 9)
  822.             sound (self, CHAN_VOICE, "player/gasp1.wav", 1, ATTN_NORM);
  823.         self.air_finished = time + 12;
  824.         self.dmg = 2;
  825.     }
  826.     else if (self.air_finished < time)
  827.     {    // drown!
  828.         if (self.pain_finished < time)
  829.         {
  830.             self.dmg = self.dmg + 2;
  831.             if (self.dmg > 15)
  832.                 self.dmg = 10;
  833.             T_Damage (self, world, world, self.dmg);
  834.             self.pain_finished = time + 1;
  835.         }
  836.     }
  837.     
  838.     if (!self.waterlevel)
  839.     {
  840.         if (self.flags & FL_INWATER)
  841.         {    
  842.             // play leave water sound
  843.             sound (self, CHAN_BODY, "misc/outwater.wav", 1, ATTN_NORM);
  844.             self.flags = self.flags - FL_INWATER;
  845.         }
  846.         return;
  847.     }
  848.  
  849.     if (self.watertype == CONTENT_LAVA)
  850.     {    // do damage
  851.         if (self.dmgtime < time)
  852.         {
  853.             if (self.radsuit_finished > time)
  854.                 self.dmgtime = time + 1;
  855.             else
  856.                 self.dmgtime = time + 0.2;
  857.  
  858.             T_Damage (self, world, world, 10*self.waterlevel);
  859.         }
  860.     }
  861.     else if (self.watertype == CONTENT_SLIME)
  862.     {    // do damage
  863.         if (self.dmgtime < time && self.radsuit_finished < time)
  864.         {
  865.             self.dmgtime = time + 1;
  866.             T_Damage (self, world, world, 4*self.waterlevel);
  867.         }
  868.     }
  869.     
  870.     if ( !(self.flags & FL_INWATER) )
  871.     {    
  872.  
  873. // player enter water sound
  874.  
  875.         if (self.watertype == CONTENT_LAVA)
  876.             sound (self, CHAN_BODY, "player/inlava.wav", 1, ATTN_NORM);
  877.         if (self.watertype == CONTENT_WATER)
  878.             sound (self, CHAN_BODY, "player/inh2o.wav", 1, ATTN_NORM);
  879.         if (self.watertype == CONTENT_SLIME)
  880.             sound (self, CHAN_BODY, "player/slimbrn2.wav", 1, ATTN_NORM);
  881.  
  882.         self.flags = self.flags + FL_INWATER;
  883.         self.dmgtime = 0;
  884.     }
  885.     
  886.     if (! (self.flags & FL_WATERJUMP) )
  887.         self.velocity = self.velocity - 0.8*self.waterlevel*frametime*self.velocity;
  888. };
  889.  
  890. void() CheckWaterJump =
  891. {
  892.     local vector start, end;
  893.  
  894. // check for a jump-out-of-water
  895.     makevectors (self.angles);
  896.     start = self.origin;
  897.     start_z = start_z + 8; 
  898.     v_forward_z = 0;
  899.     normalize(v_forward);
  900.     end = start + v_forward*24;
  901.     traceline (start, end, TRUE, self);
  902.     if (trace_fraction < 1)
  903.     {    // solid at waist
  904.         start_z = start_z + self.maxs_z - 8;
  905.         end = start + v_forward*24;
  906.         self.movedir = trace_plane_normal * -50;
  907.         traceline (start, end, TRUE, self);
  908.         if (trace_fraction == 1)
  909.         {    // open at eye level
  910.             self.flags = self.flags | FL_WATERJUMP;
  911.             self.velocity_z = 225;
  912.             self.flags = self.flags - (self.flags & FL_JUMPRELEASED);
  913.             self.teleport_time = time + 2;    // safety net
  914.             return;
  915.         }
  916.     }
  917. };
  918.  
  919.  
  920. /*
  921. ================
  922. PlayerPreThink
  923.  
  924. Called every frame before physics are run
  925. ================
  926. */
  927. void() PlayerPreThink =
  928. {
  929.     local    float    mspeed, aspeed;
  930.     local    float    r;
  931.  
  932.     if (intermission_running)
  933.     {
  934.         IntermissionThink ();    // otherwise a button could be missed between
  935.         return;                    // the think tics
  936.     }
  937.  
  938.     if (self.view_ofs == '0 0 0')
  939.         return;        // intermission or finale
  940.  
  941.     makevectors (self.v_angle);        // is this still used
  942.  
  943.     CheckRules ();
  944.     WaterMove ();
  945.  
  946.     if (self.waterlevel == 2)
  947.         CheckWaterJump ();
  948.  
  949.     if (self.deadflag >= DEAD_DEAD)
  950.     {
  951.         PlayerDeathThink ();
  952.         return;
  953.     }
  954.     
  955.     if (self.deadflag == DEAD_DYING)
  956.         return;    // dying, so do nothing
  957.  
  958.     if (self.button2)
  959.     {
  960.         PlayerJump ();
  961.     }
  962.     else
  963.         self.flags = self.flags | FL_JUMPRELEASED;
  964.  
  965. // teleporters can force a non-moving pause time    
  966.     if (time < self.pausetime)
  967.         self.velocity = '0 0 0';
  968. };
  969.     
  970. /*
  971. ================
  972. CheckPowerups
  973.  
  974. Check for turning off powerups
  975. ================
  976. */
  977. void() CheckPowerups =
  978. {
  979.     if (self.health <= 0)
  980.         return;
  981.  
  982. // invisibility
  983.     if (self.invisible_finished)
  984.     {
  985. // sound and screen flash when items starts to run out
  986.         if (self.invisible_sound < time)
  987.         {
  988.             sound (self, CHAN_AUTO, "items/inv3.wav", 0.5, ATTN_IDLE);
  989.             self.invisible_sound = time + ((random() * 3) + 1);
  990.         }
  991.  
  992.  
  993.         if (self.invisible_finished < time + 3)
  994.         {
  995.             if (self.invisible_time == 1)
  996.             {
  997.                 sprint (self, "Ring of Shadows magic is fading\n");
  998.                 stuffcmd (self, "bf\n");
  999.                 sound (self, CHAN_AUTO, "items/inv2.wav", 1, ATTN_NORM);
  1000.                 self.invisible_time = time + 1;
  1001.             }
  1002.             
  1003.             if (self.invisible_time < time)
  1004.             {
  1005.                 self.invisible_time = time + 1;
  1006.                 stuffcmd (self, "bf\n");
  1007.             }
  1008.         }
  1009.  
  1010.         if (self.invisible_finished < time)
  1011.         {    // just stopped
  1012.             self.items = self.items - IT_INVISIBILITY;
  1013.             self.invisible_finished = 0;
  1014.             self.invisible_time = 0;
  1015.         }
  1016.         
  1017.     // use the eyes
  1018.         self.frame = 0;
  1019.         self.modelindex = modelindex_eyes;
  1020.     }
  1021.     else
  1022.         self.modelindex = modelindex_player;    // don't use eyes
  1023.  
  1024. // invincibility
  1025.     if (self.invincible_finished)
  1026.     {
  1027. // sound and screen flash when items starts to run out
  1028.         if (self.invincible_finished < time + 3)
  1029.         {
  1030.             if (self.invincible_time == 1)
  1031.             {
  1032.                 sprint (self, "Protection is almost burned out\n");
  1033.                 stuffcmd (self, "bf\n");
  1034.                 sound (self, CHAN_AUTO, "items/protect2.wav", 1, ATTN_NORM);
  1035.                 self.invincible_time = time + 1;
  1036.             }
  1037.             
  1038.             if (self.invincible_time < time)
  1039.             {
  1040.                 self.invincible_time = time + 1;
  1041.                 stuffcmd (self, "bf\n");
  1042.             }
  1043.         }
  1044.         
  1045.         if (self.invincible_finished < time)
  1046.         {    // just stopped
  1047.             self.items = self.items - IT_INVULNERABILITY;
  1048.             self.invincible_time = 0;
  1049.             self.invincible_finished = 0;
  1050.         }
  1051.         if (self.invincible_finished > time)
  1052.             self.effects = self.effects | EF_DIMLIGHT;
  1053.         else
  1054.             self.effects = self.effects - (self.effects & EF_DIMLIGHT);
  1055.     }
  1056.  
  1057. // super damage
  1058.     if (self.super_damage_finished)
  1059.     {
  1060.  
  1061. // sound and screen flash when items starts to run out
  1062.  
  1063.         if (self.super_damage_finished < time + 3)
  1064.         {
  1065.             if (self.super_time == 1)
  1066.             {
  1067.                 sprint (self, "Quad Damage is wearing off\n");
  1068.                 stuffcmd (self, "bf\n");
  1069.                 sound (self, CHAN_AUTO, "items/damage2.wav", 1, ATTN_NORM);
  1070.                 self.super_time = time + 1;
  1071.             }      
  1072.             
  1073.             if (self.super_time < time)
  1074.             {
  1075.                 self.super_time = time + 1;
  1076.                 stuffcmd (self, "bf\n");
  1077.             }
  1078.         }
  1079.  
  1080.         if (self.super_damage_finished < time)
  1081.         {    // just stopped
  1082.             self.items = self.items - IT_QUAD;
  1083.             self.super_damage_finished = 0;
  1084.             self.super_time = 0;
  1085.         }
  1086.         if (self.super_damage_finished > time)
  1087.             self.effects = self.effects | EF_DIMLIGHT;
  1088.         else
  1089.             self.effects = self.effects - (self.effects & EF_DIMLIGHT);
  1090.     }    
  1091.  
  1092. // suit    
  1093.     if (self.radsuit_finished)
  1094.     {
  1095.         self.air_finished = time + 12;        // don't drown
  1096.  
  1097. // sound and screen flash when items starts to run out
  1098.         if (self.radsuit_finished < time + 3)
  1099.         {
  1100.             if (self.rad_time == 1)
  1101.             {
  1102.                 sprint (self, "Air supply in Biosuit expiring\n");
  1103.                 stuffcmd (self, "bf\n");
  1104.                 sound (self, CHAN_AUTO, "items/suit2.wav", 1, ATTN_NORM);
  1105.                 self.rad_time = time + 1;
  1106.             }
  1107.             
  1108.             if (self.rad_time < time)
  1109.             {
  1110.                 self.rad_time = time + 1;
  1111.                 stuffcmd (self, "bf\n");
  1112.             }
  1113.         }
  1114.  
  1115.         if (self.radsuit_finished < time)
  1116.         {    // just stopped
  1117.             self.items = self.items - IT_SUIT;
  1118.             self.rad_time = 0;
  1119.             self.radsuit_finished = 0;
  1120.         }
  1121.         }
  1122. };
  1123.  
  1124.  
  1125. /*
  1126. ================
  1127. PlayerPostThink
  1128.  
  1129. Called every frame after physics are run
  1130. ================
  1131. */
  1132. void() PlayerPostThink =
  1133. {
  1134.     local    float    mspeed, aspeed;
  1135.     local    float    r;
  1136.  
  1137.     if (self.view_ofs == '0 0 0')
  1138.         return;        // intermission or finale
  1139.     if (self.deadflag)
  1140.         return;
  1141.         
  1142. // do weapon stuff
  1143.  
  1144.     W_WeaponFrame ();
  1145.  
  1146. // check to see if player landed and play landing sound    
  1147.     if ((self.jump_flag < -300) && (self.flags & FL_ONGROUND) && (self.health > 0))
  1148.     {
  1149.         if (self.watertype == CONTENT_WATER)
  1150.             sound (self, CHAN_BODY, "player/h2ojump.wav", 1, ATTN_NORM);
  1151.         else if (self.jump_flag < -650)
  1152.         {
  1153.             T_Damage (self, world, world, 5); 
  1154.             sound (self, CHAN_VOICE, "player/land2.wav", 1, ATTN_NORM);
  1155.             self.deathtype = "falling";
  1156.         }
  1157.         else
  1158.             sound (self, CHAN_VOICE, "player/land.wav", 1, ATTN_NORM);
  1159.  
  1160.         self.jump_flag = 0;
  1161.     }
  1162.  
  1163.     if (!(self.flags & FL_ONGROUND))
  1164.         self.jump_flag = self.velocity_z;
  1165.  
  1166.     CheckPowerups ();
  1167. };
  1168.  
  1169.  
  1170. /*
  1171. ===========
  1172. ClientConnect
  1173.  
  1174. called when a player connects to a server
  1175. ============
  1176. */
  1177. void() ClientConnect =
  1178. {
  1179.     bprint (self.netname);
  1180.     bprint (" entered the game\n");
  1181.     
  1182. // a client connecting during an intermission can cause problems
  1183.     if (intermission_running)
  1184.         ExitIntermission ();
  1185. };
  1186.  
  1187.  
  1188. /*
  1189. ===========
  1190. ClientDisconnect
  1191.  
  1192. called when a player disconnects from a server
  1193. ============
  1194. */
  1195. void() ClientDisconnect =
  1196. {
  1197.     if (gameover)
  1198.         return;
  1199.     // if the level end trigger has been activated, just return
  1200.     // since they aren't *really* leaving
  1201.  
  1202.     // let everyone else know
  1203.     bprint (self.netname);
  1204.     bprint (" left the game with ");
  1205.     bprint (ftos(self.frags));
  1206.     bprint (" frags\n");
  1207.     sound (self, CHAN_BODY, "player/tornoff2.wav", 1, ATTN_NONE);
  1208.     set_suicide_frame ();
  1209. };
  1210.  
  1211. /*
  1212. ===========
  1213. ClientObituary
  1214.  
  1215. called when a player dies
  1216. ============
  1217. */
  1218. void(entity targ, entity attacker) ClientObituary =
  1219. {
  1220.     local    float rnum;
  1221.     local    string deathstring, deathstring2;
  1222.     rnum = random();
  1223.  
  1224.     if (targ.classname == "player")
  1225.     {
  1226.         if (attacker.classname == "teledeath")
  1227.         {
  1228.             bprint (targ.netname);
  1229.             bprint (" was telefragged by ");
  1230.             bprint (attacker.owner.netname);
  1231.             bprint ("\n");
  1232.  
  1233.             attacker.owner.frags = attacker.owner.frags + 1;
  1234.             return;
  1235.         }
  1236.  
  1237.         if (attacker.classname == "teledeath2")
  1238.         {
  1239.             bprint ("Satan's power deflects ");
  1240.             bprint (targ.netname);
  1241.             bprint ("'s telefrag\n");
  1242.  
  1243.             targ.frags = targ.frags - 1;
  1244.             return;
  1245.         }
  1246.  
  1247.         if (attacker.classname == "player")
  1248.         {
  1249.             if (targ == attacker)
  1250.             {
  1251.                 // killed self
  1252.                 attacker.frags = attacker.frags - 1;
  1253.                 bprint (targ.netname);
  1254.                 
  1255.                 if (targ.weapon == 64 && targ.waterlevel > 1)
  1256.                 {
  1257.                     bprint (" discharges into the water.\n");
  1258.                     return;
  1259.                 }
  1260.                 if (targ.weapon == 16)
  1261.                     bprint (" tries to put the pin back in\n");
  1262.                 else if (rnum)
  1263.                     bprint (" becomes bored with life\n");
  1264.                 else
  1265.                     bprint (" checks if his weapon is loaded\n");
  1266.                 return;
  1267.             }
  1268.             else
  1269.             {
  1270.                 attacker.frags = attacker.frags + 1;
  1271.  
  1272.                 rnum = attacker.weapon;
  1273.                 if (rnum == IT_AXE)
  1274.                 {
  1275.                     deathstring = " was ax-murdered by ";
  1276.                     deathstring2 = "\n";
  1277.                 }
  1278.                 if (rnum == IT_SHOTGUN)
  1279.                 {
  1280.                     deathstring = " chewed on ";
  1281.                     deathstring2 = "'s boomstick\n";
  1282.                 }
  1283.                 if (rnum == IT_SUPER_SHOTGUN)
  1284.                 {
  1285.                     deathstring = " ate 2 loads of ";
  1286.                     deathstring2 = "'s buckshot\n";
  1287.                 }
  1288.                 if (rnum == IT_NAILGUN)
  1289.                 {
  1290.                     deathstring = " was nailed by ";
  1291.                     deathstring2 = "\n";
  1292.                 }
  1293.                 if (rnum == IT_SUPER_NAILGUN)
  1294.                 {
  1295.                     deathstring = " was punctured by ";
  1296.                     deathstring2 = "\n";
  1297.                 }
  1298.                 if (rnum == IT_GRENADE_LAUNCHER)
  1299.                 {
  1300.                     deathstring = " eats ";
  1301.                     deathstring2 = "'s pineapple\n";
  1302.                     if (targ.health < -40)
  1303.                     {
  1304.                         deathstring = " was gibbed by ";
  1305.                         deathstring2 = "'s grenade\n";
  1306.                     }
  1307.                 }
  1308.                 if (rnum == IT_ROCKET_LAUNCHER)
  1309.                 {
  1310.                     deathstring = " rides ";
  1311.                     deathstring2 = "'s rocket\n";
  1312.                     if (targ.health < -40)
  1313.                     {
  1314.                         deathstring = " was gibbed by ";
  1315.                         deathstring2 = "'s rocket\n" ;
  1316.                     }
  1317.                 }
  1318.                 if (rnum == IT_LIGHTNING)
  1319.                 {
  1320.                     deathstring = " accepts ";
  1321.                     if (attacker.waterlevel > 1)
  1322.                         deathstring2 = "'s discharge\n";
  1323.                     else
  1324.                         deathstring2 = "'s shaft\n";
  1325.                 }
  1326.                 bprint (targ.netname);
  1327.                 bprint (deathstring);
  1328.                 bprint (attacker.netname);
  1329.                 bprint (deathstring2);
  1330.             }
  1331.             return;
  1332.         }
  1333.         else
  1334.         {
  1335.             targ.frags = targ.frags - 1;        // killed self
  1336.             rnum = targ.watertype;
  1337.  
  1338.             bprint (targ.netname);
  1339.             if (rnum == -3)
  1340.             {
  1341.                 if (random() < 0.5)
  1342.                     bprint (" sleeps with the fishes\n");
  1343.                 else
  1344.                     bprint (" sucks it down\n");
  1345.                 return;
  1346.             }
  1347.             else if (rnum == -4)
  1348.             {
  1349.                 if (random() < 0.5)
  1350.                     bprint (" gulped a load of slime\n");
  1351.                 else
  1352.                     bprint (" can't exist on slime alone\n");
  1353.                 return;
  1354.             }
  1355.             else if (rnum == -5)
  1356.             {
  1357.                 if (targ.health < -15)
  1358.                 {
  1359.                     bprint (" burst into flames\n");
  1360.                     return;
  1361.                 }
  1362.                 if (random() < 0.5)
  1363.                     bprint (" turned into hot slag\n");
  1364.                 else
  1365.                     bprint (" visits the Volcano God\n");
  1366.                 return;
  1367.             }
  1368.  
  1369.             if (attacker.flags & FL_MONSTER)
  1370.             {
  1371.                 if (attacker.classname == "monster_army")
  1372.                     bprint (" was shot by a Grunt\n");
  1373.                 if (attacker.classname == "monster_demon1")
  1374.                     bprint (" was eviscerated by a Fiend\n");
  1375.                 if (attacker.classname == "monster_dog")
  1376.                     bprint (" was mauled by a Rottweiler\n");
  1377.                 if (attacker.classname == "monster_dragon")
  1378.                     bprint (" was fried by a Dragon\n");
  1379.                 if (attacker.classname == "monster_enforcer")
  1380.                     bprint (" was blasted by an Enforcer\n");
  1381.                 if (attacker.classname == "monster_fish")
  1382.                     bprint (" was fed to the Rotfish\n");
  1383.                 if (attacker.classname == "monster_hell_knight")
  1384.                     bprint (" was slain by a Death Knight\n");
  1385.                 if (attacker.classname == "monster_knight")
  1386.                     bprint (" was slashed by a Knight\n");
  1387.                 if (attacker.classname == "monster_ogre")
  1388.                     bprint (" was destroyed by an Ogre\n");
  1389.                 if (attacker.classname == "monster_oldone")
  1390.                     bprint (" became one with Shub-Niggurath\n");
  1391.                 if (attacker.classname == "monster_shalrath")
  1392.                     bprint (" was exploded by a Vore\n");
  1393.                 if (attacker.classname == "monster_shambler")
  1394.                     bprint (" was smashed by a Shambler\n");
  1395.                 if (attacker.classname == "monster_tarbaby")
  1396.                     bprint (" was slimed by a Spawn\n");
  1397.                 if (attacker.classname == "monster_vomit")
  1398.                     bprint (" was vomited on by a Vomitus\n");
  1399.                 if (attacker.classname == "monster_wizard")
  1400.                     bprint (" was scragged by a Scrag\n");
  1401.                 if (attacker.classname == "monster_zombie")
  1402.                     bprint (" joins the Zombies\n");
  1403.  
  1404.                 return;
  1405.             }
  1406.             if (attacker.classname == "explo_box")
  1407.             {
  1408.                 bprint (" blew up\n");
  1409.                 return;
  1410.             }
  1411.             if (attacker.solid == SOLID_BSP && attacker != world)
  1412.             {    
  1413.                 bprint (" was squished\n");
  1414.                 return;
  1415.             }
  1416.             if (targ.deathtype == "falling")
  1417.             {
  1418.                 targ.deathtype = "";
  1419.                 bprint (" fell to his death\n");
  1420.                 return;
  1421.             }
  1422.             if (attacker.classname == "trap_shooter" || attacker.classname == "trap_spikeshooter")
  1423.             {
  1424.                 bprint (" was spiked\n");
  1425.                 return;
  1426.             }
  1427.             if (attacker.classname == "fireball")
  1428.             {
  1429.                 bprint (" ate a lavaball\n");
  1430.                 return;
  1431.             }
  1432.             if (attacker.classname == "trigger_changelevel")
  1433.             {
  1434.                 bprint (" tried to leave\n");
  1435.                 return;
  1436.             }
  1437.  
  1438.             bprint (" died\n");
  1439.         }
  1440.     }
  1441. };
  1442.